jdidata/claimsmanager repository overview

@echo off

echo. 
echo ================================================================
echo Welcome to the JDi Data Claims Manager Docker Container Run Script
echo ================================================================
echo. 
echo ***Docker Desktop MUST be installed and running BEFORE running this script***
echo. 
echo This script will run the user-specified version of Claims Manager. 
echo.
echo You may run any version that is available as a "Tag" in the "jdidata/claimsmanager" repository on Docker Hub. 
echo.
echo Please see: https://hub.docker.com/r/jdidata/claimsmanager
echo.
echo NOTE: This script is NOT designed to start Claims Manager in production environments.

SETLOCAL ENABLEDELAYEDEXPANSION

SET VERSION=
SET DB_SERVER=
SET REUSE_VOLUME=
SET EXISTS=1

SET VOLUME_NAME=jdicm_vol

if not exist env.list (
	echo. 
	echo ERROR: You must create an env.list file that will contain the runtime environment variables for Claims Manager. See SAMPLE_env.list for an example.
	exit /B
)

:prompt1
	set /p VERSION="Please enter the version/tag you want to run: (ex. 2021.01.40515-alpha): "
	IF "%VERSION%" == "" (
		goto :prompt1
	)
	echo.

:prompt2
	docker volume inspect %VOLUME_NAME%	> nul 2>&1
	IF ERRORLEVEL 1 SET EXISTS=0

	IF "%REUSE_VOLUME%" == "" (
		IF "%EXISTS%" == "1" (
			echo Provided you have not changed versions of Claims Manager, you may reuse your existing storage volume to preserve your data stored within Claims Manager.	
			CHOICE /M "Reuse existing volume?"
			IF ERRORLEVEL 1 SET REUSE_VOLUME=y
			IF ERRORLEVEL 2 SET REUSE_VOLUME=n
			echo.
			echo.
		)
	)
	
set IMAGE_NAME=jdidata/claimsmanager:%VERSION%


IF "%REUSE_VOLUME%" == "n" (
	echo Deleting volume %VOLUME_NAME%...
	docker volume rm %VOLUME_NAME% > nul 2>&1
	SET EXISTS=0
)

IF "%EXISTS%" == "0" (
	echo Creating volume %VOLUME_NAME%...
	docker volume create %VOLUME_NAME% > nul 2>&1
)

docker run -p 8080:8080 -p 8443:8443 --memory="6G" -it --rm --name jdicm_app --mount source=%VOLUME_NAME%,target=C:\JDiData\Data --env-file ./env.list %IMAGE_NAME%

user_supplied_cm_db_connection_string=
user_supplied_reporting_db_connection_string=
user_supplied_legacy_fnol_db_connection_string=
support_email_address=
from_email_address=
smtp_server=
smtp_username=
smtp_password=
smtp_port=
smtp_enable_ssl=
smtp_require_authentication=
legacy_fnol_client_factcode_value=
self_signed_ssl=y